Polarizability using automatic differentiation

Simple example for computing properties using (forward-mode) automatic differentiation. For a more classical approach and more details about computing polarizabilities, see Polarizability by linear response.

using DFTK
using LinearAlgebra
using ForwardDiff
using PseudoPotentialData

# Construct PlaneWaveBasis given a particular electric field strength
# Again we take the example of a Helium atom.
function make_basis(ε::T; a=10., Ecut=30) where {T}
    lattice = T(a) * I(3)  # lattice is a cube of ``a`` Bohrs
    # Helium at the center of the box
    pseudopotentials = PseudoFamily("cp2k.nc.sr.lda.v0_1.semicore.gth")
    atoms     = [ElementPsp(:He, pseudopotentials)]
    positions = [[1/2, 1/2, 1/2]]

    model = model_DFT(lattice, atoms, positions;
                      functionals=[:lda_x, :lda_c_vwn],
                      extra_terms=[ExternalFromReal(r -> -ε * (r[1] - a/2))],
                      symmetries=false)
    PlaneWaveBasis(model; Ecut, kgrid=[1, 1, 1])  # No k-point sampling on isolated system
end

# dipole moment of a given density (assuming the current geometry)
function dipole(basis, ρ)
    @assert isdiag(basis.model.lattice)
    a  = basis.model.lattice[1, 1]
    rr = [a * (r[1] - 1/2) for r in r_vectors(basis)]
    sum(rr .* ρ) * basis.dvol
end

# Function to compute the dipole for a given field strength
function compute_dipole(ε; tol=1e-8, kwargs...)
    scfres = self_consistent_field(make_basis(ε; kwargs...); tol)
    dipole(scfres.basis, scfres.ρ)
end;

With this in place we can compute the polarizability from finite differences (just like in the previous example):

polarizability_fd = let
    ε = 0.01
    (compute_dipole(ε) - compute_dipole(0.0)) / ε
end

1.7735579927814697

We do the same thing using automatic differentiation. Under the hood this uses custom rules to implicitly differentiate through the self-consistent field fixed-point problem. This leads to a density-functional perturbation theory problem, which is automatically set up and solved in the background.

polarizability = ForwardDiff.derivative(compute_dipole, 0.0)
println()
println("Polarizability via ForwardDiff:       $polarizability")
println("Polarizability via finite difference: $polarizability_fd")

n     Energy            log10(ΔE)   log10(Δρ)   Diag   Δtime 
---   ---------------   ---------   ---------   ----   ------
  1   -2.770638451743                   -0.53    8.0   72.2ms
  2   -2.772051705332       -2.85       -1.31    1.0   47.5ms
  3   -2.772082907521       -4.51       -2.61    1.0   83.5ms
  4   -2.772083396310       -6.31       -4.20    1.0   47.2ms
  5   -2.772083417767       -7.67       -4.78    2.0   58.4ms
  6   -2.772083417807      -10.40       -5.62    1.0   54.4ms
  7   -2.772083417811      -11.41       -6.15    2.0   62.0ms
  8   -2.772083417811      -13.37       -7.03    1.0   55.8ms
  9   -2.772083417811      -13.92       -7.40    2.0   66.2ms
 10   -2.772083417811   +  -14.01       -8.04    1.0   56.7ms
Solving response problem
Iter  Restart  Krydim  log10(res)  avg(CG)  Δtime   Comment
----  -------  ------  ----------  -------  ------  ---------------
                                      13.0  30.0ms  Non-interacting
   1        0       1       -0.60     10.0  63.6ms  
   2        0       2       -2.42      8.0   126ms  
   3        0       3       -3.55      5.0  50.2ms  
   4        0       4       -5.33      4.0  78.3ms  
   5        0       5       -7.75      1.0  42.5ms  
   6        0       6      -10.42      1.0  46.5ms  
   7        1       1       -7.42     12.0   109ms  Restart
   8        1       2       -8.48      2.0  48.4ms  
                                      12.0  68.1ms  Final orbitals

Polarizability via ForwardDiff:       1.772534995889022
Polarizability via finite difference: 1.7735579927814697