# Custom potential

We solve the 1D Gross-Pitaevskii equation with a custom potential. This is similar to Gross-Pitaevskii equation in 1D example and we show how to define local potentials attached to atoms, which allows for instance to compute forces. The custom potential is actually already defined as ElementGaussian in DFTK, and could be used as is.

using DFTK
using LinearAlgebra

First, we define a new element which represents a nucleus generating a Gaussian potential.

struct CustomPotential <: DFTK.Element
α  # Prefactor
L  # Width of the Gaussian nucleus
end

Some default values

CustomPotential() = CustomPotential(1.0, 0.5);

We extend the two methods providing access to the real and Fourier representation of the potential to DFTK.

function DFTK.local_potential_real(el::CustomPotential, r::Real)
-el.α / (√(2π) * el.L) * exp(- (r / el.L)^2 / 2)
end
function DFTK.local_potential_fourier(el::CustomPotential, p::Real)
# = ∫ V(r) exp(-ix⋅p) dx
-el.α * exp(- (p * el.L)^2 / 2)
end
Gaussian potentials and DFTK

DFTK already implements CustomPotential in form of the DFTK.ElementGaussian, so this explicit re-implementation is only provided for demonstration purposes.

We set up the lattice. For a 1D case we supply two zero lattice vectors

a = 10
lattice = a .* [[1 0 0.]; [0 0 0]; [0 0 0]];

In this example, we want to generate two Gaussian potentials generated by two "nuclei" localized at positions $x_1$ and $x_2$, that are expressed in $[0,1)$ in fractional coordinates. $|x_1 - x_2|$ should be different from $0.5$ to break symmetry and get nonzero forces.

x1 = 0.2
x2 = 0.8
positions = [[x1, 0, 0], [x2, 0, 0]]
gauss     = CustomPotential()
atoms     = [gauss, gauss];

We setup a Gross-Pitaevskii model

C = 1.0
α = 2;
n_electrons = 1  # Increase this for fun
terms = [Kinetic(),
AtomicLocal(),
LocalNonlinearity(ρ -> C * ρ^α)]
model = Model(lattice, atoms, positions; n_electrons, terms,
spin_polarization=:spinless);  # use "spinless electrons"

We discretize using a moderate Ecut and run a SCF algorithm to compute forces afterwards. As there is no ionic charge associated to gauss we have to specify a starting density and we choose to start from a zero density.

basis = PlaneWaveBasis(model; Ecut=500, kgrid=(1, 1, 1))
ρ = zeros(eltype(basis), basis.fft_size..., 1)
scfres = self_consistent_field(basis; tol=1e-5, ρ)
scfres.energies
Energy breakdown (in Ha):
Kinetic             0.0380296
AtomicLocal         -0.3163466
LocalNonlinearity   0.1212607

total               -0.157056406907

Computing the forces can then be done as usual:

compute_forces(scfres)
2-element Vector{StaticArraysCore.SVector{3, Float64}}:
[-0.055680422895027185, -0.0, -0.0]
[0.0556891620594341, -0.0, -0.0]

Extract the converged total local potential

tot_local_pot = DFTK.total_local_potential(scfres.ham)[:, 1, 1]; # use only dimension 1

Extract other quantities before plotting them

ρ = scfres.ρ[:, 1, 1, 1]        # converged density, first spin component
ψ_fourier = scfres.ψ[1][:, 1]   # first k-point, all G components, first eigenvector
101-element Vector{ComplexF64}:
0.5276511335778729 + 0.817124477297661im
0.05422826832654748 + 0.08397675396328648im
-0.06425189841997805 - 0.0995009607917026im
-0.027912717877972608 - 0.04322391478680244im
0.004870501634702208 + 0.00754327909952087im
0.0074119958043363555 + 0.011478412907327701im
0.0010695388580371182 + 0.0016559780446160693im
-0.0011896073933755924 - 0.001842417033947405im
-0.0005124660219694361 - 0.0007935208391117075im
7.794416491254159e-5 + 0.00012080752318654058im
⋮
7.803798442449857e-5 + 0.00012074755756388051im
-0.0005123856189882379 - 0.000793572381391406im
-0.0011897738165523785 - 0.0018423102668689833im
0.0010692497960612753 + 0.0016561655141015801im
0.007412123550993974 + 0.011478331021702598im
0.004871215194144513 + 0.007542815584804543im
-0.027910959632208937 - 0.04322504837470265im
-0.06425189078933058 - 0.09950096467603711im
0.05422685877097642 + 0.08397766400200732im

Transform the wave function to real space and fix the phase:

ψ = ifft(basis, basis.kpoints[1], ψ_fourier)[:, 1, 1]
ψ /= (ψ[div(end, 2)] / abs(ψ[div(end, 2)]));

using Plots
x = a * vec(first.(DFTK.r_vectors(basis)))
p = plot(x, real.(ψ), label="real(ψ)")
plot!(p, x, imag.(ψ), label="imag(ψ)")
plot!(p, x, ρ, label="ρ")
plot!(p, x, tot_local_pot, label="tot local pot")