# Polarizability by linear response

We compute the polarizability of a Helium atom. The polarizability is defined as the change in dipole moment

\[μ = ∫ r ρ(r) dr\]

with respect to a small uniform electric field $E = -x$.

We compute this in two ways: first by finite differences (applying a finite electric field), then by linear response. Note that DFTK is not really adapted to isolated atoms because it uses periodic boundary conditions. Nevertheless we can simply embed the Helium atom in a large enough box (although this is computationally wasteful).

As in other tests, this is not fully converged, convergence parameters were simply selected for fast execution on CI,

```
using DFTK
using LinearAlgebra
a = 10.
lattice = a * I(3) # cube of ``a`` bohrs
# Helium at the center of the box
atoms = [ElementPsp(:He; psp=load_psp("hgh/lda/He-q2"))]
positions = [[1/2, 1/2, 1/2]]
kgrid = [1, 1, 1] # no k-point sampling for an isolated system
Ecut = 30
tol = 1e-8
# dipole moment of a given density (assuming the current geometry)
function dipole(basis, ρ)
rr = [(r[1] - a/2) for r in r_vectors_cart(basis)]
sum(rr .* ρ) * basis.dvol
end;
```

## Using finite differences

We first compute the polarizability by finite differences. First compute the dipole moment at rest:

```
model = model_DFT(lattice, atoms, positions;
functionals=LDA(), symmetries=false)
basis = PlaneWaveBasis(model; Ecut, kgrid)
res = self_consistent_field(basis; tol)
μref = dipole(basis, res.ρ)
```

`-0.00013457202504715986`

Then in a small uniform field:

```
ε = .01
model_ε = model_DFT(lattice, atoms, positions;
functionals=LDA(),
extra_terms=[ExternalFromReal(r -> -ε * (r[1] - a/2))],
symmetries=false)
basis_ε = PlaneWaveBasis(model_ε; Ecut, kgrid)
res_ε = self_consistent_field(basis_ε; tol)
με = dipole(basis_ε, res_ε.ρ)
```

`0.017612220734923727`

```
polarizability = (με - μref) / ε
println("Reference dipole: $μref")
println("Displaced dipole: $με")
println("Polarizability : $polarizability")
```

```
Reference dipole: -0.00013457202504715986
Displaced dipole: 0.017612220734923727
Polarizability : 1.7746792759970886
```

The result on more converged grids is very close to published results. For example DOI 10.1039/C8CP03569E quotes **1.65** with LSDA and **1.38** with CCSD(T).

## Using linear response

Now we use linear response to compute this analytically; we refer to standard textbooks for the formalism. In the following, $χ_0$ is the independent-particle polarizability, and $K$ the Hartree-exchange-correlation kernel. We denote with $δV_{\rm ext}$ an external perturbing potential (like in this case the uniform electric field). Then:

\[δρ = χ_0 δV = χ_0 (δV_{\rm ext} + K δρ),\]

which implies

\[δρ = (1-χ_0 K)^{-1} χ_0 δV_{\rm ext}.\]

From this we identify the polarizability operator to be $χ = (1-χ_0 K)^{-1} χ_0$. Numerically, we apply $χ$ to $δV = -x$ by solving a linear equation (the Dyson equation) iteratively.

```
using KrylovKit
# Apply ``(1- χ_0 K)``
function dielectric_operator(δρ)
δV = apply_kernel(basis, δρ; res.ρ)
χ0δV = apply_χ0(res, δV)
δρ - χ0δV
end
# `δVext` is the potential from a uniform field interacting with the dielectric dipole
# of the density.
δVext = [-(r[1] - a/2) for r in r_vectors_cart(basis)]
δVext = cat(δVext; dims=4)
# Apply ``χ_0`` once to get non-interacting dipole
δρ_nointeract = apply_χ0(res, δVext)
# Solve Dyson equation to get interacting dipole
δρ = linsolve(dielectric_operator, δρ_nointeract, verbosity=3)[1]
println("Non-interacting polarizability: $(dipole(basis, δρ_nointeract))")
println("Interacting polarizability: $(dipole(basis, δρ))")
```

```
WARNING: using KrylovKit.basis in module Main conflicts with an existing identifier.
[ Info: GMRES linsolve in iter 1; step 1: normres = 2.493920638793e-01
[ Info: GMRES linsolve in iter 1; step 2: normres = 3.766549869724e-03
[ Info: GMRES linsolve in iter 1; step 3: normres = 2.852733914839e-04
[ Info: GMRES linsolve in iter 1; step 4: normres = 4.694593687866e-06
[ Info: GMRES linsolve in iter 1; step 5: normres = 1.088787558798e-08
[ Info: GMRES linsolve in iter 1; step 6: normres = 6.274918144898e-11
[ Info: GMRES linsolve in iter 1; step 7: normres = 7.133422587426e-13
[ Info: GMRES linsolve in iter 1; finished at step 7: normres = 7.133422587426e-13
[ Info: GMRES linsolve in iter 2; step 1: normres = 1.668575021454e-09
[ Info: GMRES linsolve in iter 2; step 2: normres = 2.919545058903e-11
[ Info: GMRES linsolve in iter 2; step 3: normres = 4.707887073492e-12
[ Info: GMRES linsolve in iter 2; step 4: normres = 6.249183805947e-14
[ Info: GMRES linsolve in iter 2; finished at step 4: normres = 6.249183805947e-14
┌ Info: GMRES linsolve converged at iteration 2, step 4:
│ * norm of residual = 6.21806817434195e-14
└ * number of operations = 13
Non-interacting polarizability: 1.9257125154254693
Interacting polarizability: 1.7736548409358563
```

As expected, the interacting polarizability matches the finite difference result. The non-interacting polarizability is higher.