Collinear spin and magnetic systems
In this example we consider iron in the BCC phase. To show that this material is ferromagnetic we will model it once allowing collinear spin polarization and once without and compare the resulting SCF energies. In particular the ground state can only be found if collinear spins are allowed.
First we setup BCC iron without spin polarization using a single iron atom inside the unit cell.
using DFTK
a = 5.42352 # Bohr
lattice = a / 2 * [[-1 1 1];
[ 1 -1 1];
[ 1 1 -1]]
atoms = [ElementPsp(:Fe; psp=load_psp("hgh/lda/Fe-q8.hgh"))]
positions = [zeros(3)];To get the ground-state energy we use an LDA model and rather moderate discretisation parameters.
kgrid = [3, 3, 3] # k-point grid (Regular Monkhorst-Pack grid)
Ecut = 15 # kinetic energy cutoff in Hartree
model_nospin = model_LDA(lattice, atoms, positions, temperature=0.01)
basis_nospin = PlaneWaveBasis(model_nospin; kgrid, Ecut)
scfres_nospin = self_consistent_field(basis_nospin; tol=1e-4, mixing=KerkerDosMixing());n Energy log10(ΔE) log10(Δρ) Diag Δtime
--- --------------- --------- --------- ---- ------
1 -16.65005495346 -0.48 5.8 98.4ms
2 -16.65071026498 -3.18 -1.01 1.0 17.9ms
3 -16.65080953906 -4.00 -2.32 1.2 18.0ms
4 -16.65082388453 -4.84 -2.84 2.0 21.2ms
5 -16.65082455908 -6.17 -3.27 1.2 18.2ms
6 -16.65082467403 -6.94 -3.75 1.5 19.1ms
7 -16.65082469700 -7.64 -4.24 2.0 21.3msscfres_nospin.energiesEnergy breakdown (in Ha):
Kinetic 15.9209555
AtomicLocal -5.0693828
AtomicNonlocal -5.2202943
Ewald -21.4723040
PspCorrection 1.8758831
Hartree 0.7793617
Xc -3.4467558
Entropy -0.0182880
total -16.650824697005Since we did not specify any initial magnetic moment on the iron atom, DFTK will automatically assume that a calculation with only spin-paired electrons should be performed. As a result the obtained ground state features no spin-polarization.
Now we repeat the calculation, but give the iron atom an initial magnetic moment. For specifying the magnetic moment pass the desired excess of spin-up over spin-down electrons at each centre to the Model and the guess density functions. In this case we seek the state with as many spin-parallel $d$-electrons as possible. In our pseudopotential model the 8 valence electrons are 1 pair of $s$-electrons, 1 pair of $d$-electrons and 4 unpaired $d$-electrons giving a desired magnetic moment of 4 at the iron centre. The structure (i.e. pair mapping and order) of the magnetic_moments array needs to agree with the atoms array and 0 magnetic moments need to be specified as well.
magnetic_moments = [4];Unlike all other quantities magnetisation and magnetic moments in DFTK are given in units of the Bohr magneton $μ_B$, which in atomic units has the value $\frac{1}{2}$. Since $μ_B$ is (roughly) the magnetic moment of a single electron the advantage is that one can directly think of these quantities as the excess of spin-up electrons or spin-up electron density.
We repeat the calculation using the same model as before. DFTK now detects the non-zero moment and switches to a collinear calculation.
model = model_LDA(lattice, atoms, positions; magnetic_moments, temperature=0.01)
basis = PlaneWaveBasis(model; Ecut, kgrid)
ρ0 = guess_density(basis, magnetic_moments)
scfres = self_consistent_field(basis, tol=1e-6; ρ=ρ0, mixing=KerkerDosMixing());n Energy log10(ΔE) log10(Δρ) Magnet Diag Δtime
--- --------------- --------- --------- ------ ---- ------
1 -16.66167531118 -0.51 2.618 5.4 61.7ms
2 -16.66826255458 -2.18 -1.09 2.445 1.5 36.8ms
3 -16.66905089337 -3.10 -2.07 2.341 2.0 40.5ms
4 -16.66909844980 -4.32 -2.66 2.305 1.4 50.6ms
5 -16.66910300763 -5.34 -3.01 2.295 1.8 39.3ms
6 -16.66910414406 -5.94 -3.50 2.286 1.8 39.1ms
7 -16.66910416882 -7.61 -3.77 2.286 1.6 37.7ms
8 -16.66910417340 -8.34 -4.29 2.285 1.6 38.9ms
9 -16.66910417505 -8.78 -4.90 2.286 1.5 37.1ms
10 -16.66910417505 -11.24 -5.15 2.286 2.0 42.3ms
11 -16.66910417507 -10.79 -5.67 2.286 1.0 34.6ms
12 -16.66910417509 -10.73 -6.13 2.286 1.8 41.7msscfres.energiesEnergy breakdown (in Ha):
Kinetic 16.2947206
AtomicLocal -5.2227267
AtomicNonlocal -5.4100288
Ewald -21.4723040
PspCorrection 1.8758831
Hartree 0.8191964
Xc -3.5406836
Entropy -0.0131612
total -16.669104175088DFTK does not store the magnetic_moments inside the Model, but only uses them to determine the lattice symmetries. This step was taken to keep Model (which contains the physical model) independent of the details of the numerical details such as the initial guess for the spin density.
In direct comparison we notice the first, spin-paired calculation to be a little higher in energy
println("No magnetization: ", scfres_nospin.energies.total)
println("Magnetic case: ", scfres.energies.total)
println("Difference: ", scfres.energies.total - scfres_nospin.energies.total);No magnetization: -16.65082469700496
Magnetic case: -16.66910417508761
Difference: -0.018279478082650513Notice that with the small cutoffs we use to generate the online documentation the calculation is far from converged. With more realistic parameters a larger energy difference of about 0.1 Hartree is obtained.
The spin polarization in the magnetic case is visible if we consider the occupation of the spin-up and spin-down Kohn-Sham orbitals. Especially for the $d$-orbitals these differ rather drastically. For example for the first $k$-point:
iup = 1
idown = iup + length(scfres.basis.kpoints) ÷ 2
@show scfres.occupation[iup][1:7]
@show scfres.occupation[idown][1:7];(scfres.occupation[iup])[1:7] = [1.0, 0.9999987814447996, 0.9999987814447996, 0.9999987814447996, 0.9582254235889524, 0.9582254235889309, 1.1267187682358537e-29]
(scfres.occupation[idown])[1:7] = [1.0, 0.8438918218635503, 0.8438918218635049, 0.8438918218633148, 8.140755627540045e-6, 8.140755627537702e-6, 1.6220639884553242e-32]Similarly the eigenvalues differ
@show scfres.eigenvalues[iup][1:7]
@show scfres.eigenvalues[idown][1:7];(scfres.eigenvalues[iup])[1:7] = [-0.06935860146028565, 0.356885542148677, 0.356885542148677, 0.3568855421486833, 0.461736025371502, 0.4617360253715074, 1.1596205569231592]
(scfres.eigenvalues[idown])[1:7] = [-0.031257419872751796, 0.4761892256252599, 0.47618922562526333, 0.47618922562527777, 0.610250170717758, 0.6102501707177609, 1.2250542122979453]For collinear calculations the kpoints field of the PlaneWaveBasis object contains each $k$-point coordinate twice, once associated with spin-up and once with down-down. The list first contains all spin-up $k$-points and then all spin-down $k$-points, such that iup and idown index the same $k$-point, but differing spins.
We can observe the spin-polarization by looking at the density of states (DOS) around the Fermi level, where the spin-up and spin-down DOS differ.
using Plots
bands_666 = compute_bands(scfres, MonkhorstPack(6, 6, 6)) # Increase kgrid to get nicer DOS.
plot_dos(bands_666)
Note that if same k-grid as SCF should be employed, a simple plot_dos(scfres) is sufficient.
Similarly the band structure shows clear differences between both spin components.
using Unitful
using UnitfulAtomic
bands_kpath = compute_bands(scfres; kline_density=6)
plot_bandstructure(bands_kpath)