# Tutorial

This document provides an overview of the structure of the code and how to access basic information about calculations. Basic familiarity with the concepts of plane-wave density functional theory is assumed throughout. Feel free to take a look at the Periodic problems or the Introductory resources chapters for some introductory material on the topic.

We use rough parameters in order to be able to automatically generate this documentation very quickly. Therefore results are far from converged. Tighter thresholds and larger grids should be used for more realistic results.

For our discussion we will use the classic example of computing the LDA ground state of the silicon crystal. Performing such a calculation roughly proceeds in three steps.

```
using DFTK
using Plots
using Unitful
using UnitfulAtomic
# 1. Define lattice and atomic positions
a = 5.431u"angstrom" # Silicon lattice constant
lattice = a / 2 * [[0 1 1.]; # Silicon lattice vectors
[1 0 1.]; # specified column by column
[1 1 0.]];
```

By default, all numbers passed as arguments are assumed to be in atomic units. Quantities such as temperature, energy cutoffs, lattice vectors, and the k-point grid spacing can optionally be annotated with Unitful units, which are automatically converted to the atomic units used internally. For more details, see the Unitful package documentation and the UnitfulAtomic.jl package.

```
# Load HGH pseudopotential for Silicon
Si = ElementPsp(:Si; psp=load_psp("hgh/lda/Si-q4"))
# Specify type and positions of atoms
atoms = [Si, Si]
positions = [ones(3)/8, -ones(3)/8]
```

```
2-element Vector{Vector{Float64}}:
[0.125, 0.125, 0.125]
[-0.125, -0.125, -0.125]
```

Note that DFTK supports a few other ways to supply atomistic structures, see for example the sections on AtomsBase integration and Input and output formats for details.

```
# 2. Select model and basis
model = model_DFT(lattice, atoms, positions; functionals=LDA())
kgrid = [4, 4, 4] # k-point grid (Regular Monkhorst-Pack grid)
Ecut = 7 # kinetic energy cutoff
# Ecut = 190.5u"eV" # Could also use eV or other energy-compatible units
basis = PlaneWaveBasis(model; Ecut, kgrid)
# Note the implicit passing of keyword arguments here:
# this is equivalent to PlaneWaveBasis(model; Ecut=Ecut, kgrid=kgrid)
# 3. Run the SCF procedure to obtain the ground state
scfres = self_consistent_field(basis, tol=1e-5);
```

```
n Energy log10(ΔE) log10(Δρ) Diag Δtime
--- --------------- --------- --------- ---- ------
1 -7.900455367652 -0.70 4.8 53.9ms
2 -7.905005384531 -2.34 -1.52 1.0 25.3ms
3 -7.905178398258 -3.76 -2.53 1.2 26.8ms
4 -7.905210453143 -4.49 -2.84 2.5 36.5ms
5 -7.905211093645 -6.19 -2.98 1.1 51.4ms
6 -7.905211515892 -6.37 -4.56 1.0 25.6ms
7 -7.905211531143 -7.82 -4.62 2.8 40.4ms
8 -7.905211531385 -9.62 -5.12 1.0 26.0ms
```

That's it! Now you can get various quantities from the result of the SCF. For instance, the different components of the energy:

`scfres.energies`

```
Energy breakdown (in Ha):
Kinetic 3.1020959
AtomicLocal -2.1987836
AtomicNonlocal 1.7296092
Ewald -8.3979253
PspCorrection -0.2946254
Hartree 0.5530388
Xc -2.3986211
total -7.905211531385
```

Eigenvalues:

`stack(scfres.eigenvalues)`

```
7×8 Matrix{Float64}:
-0.176942 -0.14744 -0.0911691 … -0.101219 -0.0239769 -0.0184078
0.261073 0.116915 0.00482517 0.0611645 -0.0239769 -0.0184078
0.261073 0.23299 0.216734 0.121636 0.155532 0.117747
0.261073 0.23299 0.216734 0.212134 0.155532 0.117747
0.354532 0.335109 0.317102 0.350436 0.285692 0.417258
0.354532 0.389829 0.384601 … 0.436926 0.285692 0.417429
0.354532 0.389829 0.384601 0.449228 0.627542 0.443806
```

`eigenvalues`

is an array (indexed by k-points) of arrays (indexed by eigenvalue number).

The resulting matrix is 7 (number of computed eigenvalues) by 8 (number of irreducible k-points). There are 7 eigenvalues per k-point because there are 4 occupied states in the system (4 valence electrons per silicon atom, two atoms per unit cell, and paired spins), and the eigensolver gives itself some breathing room by computing some extra states (see the `bands`

argument to `self_consistent_field`

as well as the `AdaptiveBands`

documentation). There are only 8 k-points (instead of 4x4x4) because symmetry has been used to reduce the amount of computations to just the irreducible k-points (see Crystal symmetries for details).

We can check the occupations ...

`stack(scfres.occupation)`

```
7×8 Matrix{Float64}:
2.0 2.0 2.0 2.0 2.0 2.0 2.0 2.0
2.0 2.0 2.0 2.0 2.0 2.0 2.0 2.0
2.0 2.0 2.0 2.0 2.0 2.0 2.0 2.0
2.0 2.0 2.0 2.0 2.0 2.0 2.0 2.0
0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0
0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0
0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0
```

... and density, where we use that the density objects in DFTK are indexed as ρ[ix, iy, iz, iσ], i.e. first in the 3-dimensional real-space grid and then in the spin component.

```
rvecs = collect(r_vectors(basis))[:, 1, 1] # slice along the x axis
x = [r[1] for r in rvecs] # only keep the x coordinate
plot(x, scfres.ρ[1, :, 1, 1], label="", xlabel="x", ylabel="ρ", marker=2)
```

We can also perform various postprocessing steps: We can get the Cartesian forces (in Hartree / Bohr):

`compute_forces_cart(scfres)`

```
2-element Vector{StaticArraysCore.SVector{3, Float64}}:
[-3.513962498552321e-16, -2.6436176301153133e-16, -1.563244873629801e-16]
[-4.3118951175535095e-16, 5.4806929014990114e-17, -1.6744675432673545e-16]
```

As expected, they are numerically zero in this highly symmetric configuration. We could also compute a band structure,

`plot_bandstructure(scfres; kline_density=10)`

or plot a density of states, for which we increase the kgrid a bit to get smoother plots:

```
bands = compute_bands(scfres, MonkhorstPack(6, 6, 6))
plot_dos(bands; temperature=1e-3, smearing=Smearing.FermiDirac())
```

Note that directly employing the `scfres`

also works, but the results are much cruder:

`plot_dos(scfres; temperature=1e-3, smearing=Smearing.FermiDirac())`