Hubbard correction (DFT+U)
In this example, we'll plot the DOS and projected DOS of Nickel Oxide with and without the Hubbard term correction.
using DFTK
using PseudoPotentialData
using Unitful
using UnitfulAtomic
using PlotsDefine the geometry and pseudopotential
a = 7.9 # Nickel Oxide lattice constant in Bohr
lattice = a * [[ 1.0 0.5 0.5];
[ 0.5 1.0 0.5];
[ 0.5 0.5 1.0]]
pseudopotentials = PseudoFamily("dojo.nc.sr.pbe.v0_4_1.standard.upf")
Ni = ElementPsp(:Ni, pseudopotentials)
O = ElementPsp(:O, pseudopotentials)
atoms = [Ni, O, Ni, O]
positions = [zeros(3), ones(3) / 4, ones(3) / 2, ones(3) * 3 / 4]
magnetic_moments = [2, 0, -1, 0]4-element Vector{Int64}:
2
0
-1
0First, we run an SCF and band computation without the Hubbard term
model = model_DFT(lattice, atoms, positions; temperature=5e-3,
functionals=PBE(), magnetic_moments)
basis = PlaneWaveBasis(model; Ecut=20, kgrid=[2, 2, 2])
scfres = self_consistent_field(basis; tol=1e-6, ρ=guess_density(basis, magnetic_moments))
bands = compute_bands(scfres, MonkhorstPack(4, 4, 4))
lowest_unocc_band = findfirst(ε -> ε-bands.εF > 0, bands.eigenvalues[1])
band_gap = bands.eigenvalues[1][lowest_unocc_band] - bands.eigenvalues[1][lowest_unocc_band-1]0.08219330192976021Then we plot the DOS and the PDOS for the relevant 3D (pseudo)atomic projector
εF = bands.εF
width = 5.0u"eV"
εrange = (εF - austrip(width), εF + austrip(width))
p = plot_dos(bands; εrange, colors=[1, 1])
plot_pdos(bands; p, iatom=1, label="3D", colors=[3, 4], εrange)
To perform and Hubbard computation, we have to define the Hubbard manifold and associated constant.
In DFTK there are a few ways to construct the OrbitalManifold. Here, we will apply the Hubbard correction on the 3D orbital of all nickel atoms. To select all nickel atoms, we can:
- Pass the
Nielement directly. - Pass the
:Nisymbol. - Pass the list of atom indices, here
[1, 3].
To select the orbitals, it is recommended to use their label, such as "3D" for PseudoDojo pseudopotentials.
Note that "manifold" is the standard term used in the literature for the set of atomic orbitals used to compute the Hubbard correction, but it is not meant in the mathematical sense.
U = 10u"eV"
# Alternative:
# manifold = OrbitalManifold(:Ni, "3D")
# Alternative:
# manifold = OrbitalManifold([1, 3], "3D")
manifold = OrbitalManifold(Ni, "3D")OrbitalManifold(Ni, "3D")Run SCF with a DFT+U setup, notice the extra_terms keyword argument, setting up the Hubbard +U term. It is also possible to set up multiple manifolds with different U values by passing each pair as a separate entry in the Hubbard constructor (i.e. Hubbard(manifold1 => U1, manifold2 => U2, etc.)) or as two vectors (i.e. Hubbard([manifold1, manifold2, etc.], [U1, U2, etc.])).
model = model_DFT(lattice, atoms, positions; extra_terms=[Hubbard(manifold => U)],
functionals=PBE(), temperature=5e-3, magnetic_moments)
basis = PlaneWaveBasis(model; Ecut=20, kgrid=[2, 2, 2])
scfres = self_consistent_field(basis; tol=1e-6, ρ=guess_density(basis, magnetic_moments));n Energy log10(ΔE) log10(Δρ) Magnet |Magn| Diag Δtime
--- --------------- --------- --------- ------ ------ ---- ------
1 -361.3824219188 0.07 1.334 3.443 6.8 4.01s
2 -362.9706085376 0.20 -0.10 0.224 3.873 2.5 10.5s
3 -363.1934892623 -0.65 -0.20 0.000 3.776 3.1 2.47s
4 -363.2414176058 -1.32 -0.29 0.000 3.781 2.1 1.73s
5 -363.3690752088 -0.89 -0.31 0.000 3.683 4.0 2.71s
6 -363.3861104493 -1.77 -0.48 -0.000 3.652 2.0 1.73s
7 -363.3969348138 -1.97 -1.11 -0.000 3.674 2.8 1.94s
8 -363.3933177569 + -2.44 -0.91 0.000 3.678 2.0 2.05s
9 -363.3967179473 -2.47 -1.08 0.000 3.657 1.0 1.42s
10 -363.3974631765 -3.13 -1.34 0.000 3.647 1.0 1.41s
11 -363.3975719104 -3.96 -1.43 0.000 3.644 1.0 1.74s
12 -363.3975918551 -4.70 -1.42 0.000 3.643 1.0 1.44s
13 -363.3976969717 -3.98 -2.05 0.000 3.643 1.0 1.42s
14 -363.3977049261 -5.10 -2.60 -0.000 3.645 1.0 1.76s
15 -363.3977023973 + -5.60 -2.53 -0.000 3.645 1.8 1.63s
16 -363.3977035204 -5.95 -2.60 -0.000 3.646 1.0 1.42s
17 -363.3977056235 -5.68 -2.78 0.000 3.646 1.0 1.76s
18 -363.3977079232 -5.64 -2.91 0.000 3.647 1.0 1.42s
19 -363.3977093326 -5.85 -3.14 0.000 3.648 1.1 1.43s
20 -363.3977099155 -6.23 -3.57 0.000 3.648 2.0 1.96s
21 -363.3977100050 -7.05 -4.16 0.000 3.648 2.0 1.71s
22 -363.3977099826 + -7.65 -3.87 0.000 3.649 2.4 1.68s
23 -363.3977100092 -7.58 -4.28 0.000 3.648 1.9 1.88s
24 -363.3977100148 -8.25 -4.45 0.000 3.648 1.2 1.46s
25 -363.3977100157 -9.02 -4.49 0.000 3.648 1.1 1.44s
26 -363.3977100156 + -10.05 -4.53 0.000 3.648 1.0 1.76s
27 -363.3977100176 -8.71 -5.46 0.000 3.648 1.9 1.58s
28 -363.3977100177 -10.04 -4.99 0.000 3.648 2.5 1.82s
29 -363.3977100178 -10.04 -5.29 0.000 3.648 2.0 2.04s
30 -363.3977100178 -10.51 -5.38 0.000 3.648 1.0 1.42s
31 -363.3977100178 -10.74 -5.96 0.000 3.648 1.0 1.41s
32 -363.3977100178 -10.87 -5.88 0.000 3.648 2.8 2.14s
33 -363.3977100178 -11.18 -5.75 0.000 3.648 1.0 1.40s
34 -363.3977100178 -11.41 -5.80 0.000 3.648 1.4 1.47s
35 -363.3977100179 -11.61 -6.19 0.000 3.648 1.2 1.80s
Run band computation
bands_hub = compute_bands(scfres, MonkhorstPack(4, 4, 4))
lowest_unocc_band = findfirst(ε -> ε-bands_hub.εF > 0, bands_hub.eigenvalues[1])
band_gap = bands_hub.eigenvalues[1][lowest_unocc_band] - bands_hub.eigenvalues[1][lowest_unocc_band-1]0.11667618139626335With the electron localization introduced by the Hubbard term, the band gap has now opened, reflecting the experimental insulating behaviour of Nickel Oxide.
εF = bands_hub.εF
εrange = (εF - austrip(width), εF + austrip(width))
p = plot_dos(bands_hub; p, colors=[2, 2], εrange)
plot_pdos(bands_hub; p, iatom=1, label="3D", colors=[3, 4], εrange)