Collinear spin and magnetic systems

In this example we consider iron in the BCC phase. To show that this material is ferromagnetic we will model it once allowing collinear spin polarization and once without and compare the resulting SCF energies. In particular the ground state can only be found if collinear spins are allowed.

First we setup BCC iron without spin polarization using a single iron atom inside the unit cell.

using DFTK

a = 5.42352  # Bohr
lattice = a / 2 * [[-1  1  1];
                   [ 1 -1  1];
                   [ 1  1 -1]]
atoms     = [ElementPsp(:Fe, psp=load_psp("hgh/lda/Fe-q8.hgh"))]
positions = [zeros(3)];

To get the ground-state energy we use an LDA model and rather moderate discretisation parameters.

kgrid = [3, 3, 3]  # k-point grid (Regular Monkhorst-Pack grid)
Ecut = 15          # kinetic energy cutoff in Hartree
model_nospin = model_LDA(lattice, atoms, positions, temperature=0.01)
basis_nospin = PlaneWaveBasis(model_nospin; kgrid, Ecut)

scfres_nospin = self_consistent_field(basis_nospin; tol=1e-6, mixing=KerkerDosMixing());
n     Energy            log10(ΔE)   log10(Δρ)   Diag
---   ---------------   ---------   ---------   ----
  1   -16.65001306055                   -0.48    5.2
  2   -16.65069832245       -3.16       -1.01    1.0
  3   -16.65080957237       -3.95       -2.31    1.8
  4   -16.65082423632       -4.83       -2.81    3.0
  5   -16.65082466915       -6.36       -3.29    2.0
scfres_nospin.energies
Energy breakdown (in Ha):
    Kinetic             15.9192378
    AtomicLocal         -5.0684384
    AtomicNonlocal      -5.2193352
    Ewald               -21.4723040
    PspCorrection       1.8758831 
    Hartree             0.7790818 
    Xc                  -3.4466625
    Entropy             -0.0182873

    total               -16.650824669147

Since we did not specify any initial magnetic moment on the iron atom, DFTK will automatically assume that a calculation with only spin-paired electrons should be performed. As a result the obtained ground state features no spin-polarization.

Now we repeat the calculation, but give the iron atom an initial magnetic moment. For specifying the magnetic moment pass the desired excess of spin-up over spin-down electrons at each centre to the Model and the guess density functions. In this case we seek the state with as many spin-parallel $d$-electrons as possible. In our pseudopotential model the 8 valence electrons are 2 pair of $s$-electrons, 1 pair of $d$-electrons and 4 unpaired $d$-electrons giving a desired magnetic moment of 4 at the iron centre. The structure (i.e. pair mapping and order) of the magnetic_moments array needs to agree with the atoms array and 0 magnetic moments need to be specified as well.

magnetic_moments = [4];
Units of the magnetisation and magnetic moments in DFTK

Unlike all other quantities magnetisation and magnetic moments in DFTK are given in units of the Bohr magneton $μ_B$, which in atomic units has the value $\frac{1}{2}$. Since $μ_B$ is (roughly) the magnetic moment of a single electron the advantage is that one can directly think of these quantities as the excess of spin-up electrons or spin-up electron density.

We repeat the calculation using the same model as before. DFTK now detects the non-zero moment and switches to a collinear calculation.

model = model_LDA(lattice, atoms, positions; magnetic_moments, temperature=0.01)
basis = PlaneWaveBasis(model; Ecut, kgrid)
ρ0 = guess_density(basis, magnetic_moments)
scfres = self_consistent_field(basis, tol=1e-6; ρ=ρ0, mixing=KerkerDosMixing());
n     Energy            log10(ΔE)   log10(Δρ)   Magnet   Diag
---   ---------------   ---------   ---------   ------   ----
  1   -16.66159771127                   -0.51    2.618    4.9
  2   -16.66809651043       -2.19       -1.09    2.445    1.4
  3   -16.66905540787       -3.02       -2.06    2.337    2.2
  4   -16.66910030014       -4.35       -2.72    2.303    2.0
  5   -16.66910301354       -5.57       -2.91    2.296    2.6
  6   -16.66910443801       -5.85       -3.52    2.286    2.2
  7   -16.66910446004       -7.66       -3.84    2.286    2.5
scfres.energies
Energy breakdown (in Ha):
    Kinetic             16.2944969
    AtomicLocal         -5.2225768
    AtomicNonlocal      -5.4099013
    Ewald               -21.4723040
    PspCorrection       1.8758831 
    Hartree             0.8191509 
    Xc                  -3.5406935
    Entropy             -0.0131597

    total               -16.669104460035
Model and magnetic moments

DFTK does not store the magnetic_moments inside the Model, but only uses them to determine the lattice symmetries. This step was taken to keep Model (which contains the physical model) independent of the details of the numerical details such as the initial guess for the spin density.

In direct comparison we notice the first, spin-paired calculation to be a little higher in energy

println("No magnetization: ", scfres_nospin.energies.total)
println("Magnetic case:    ", scfres.energies.total)
println("Difference:       ", scfres.energies.total - scfres_nospin.energies.total);
No magnetization: -16.650824669146918
Magnetic case:    -16.669104460035424
Difference:       -0.018279790888506398

Notice that with the small cutoffs we use to generate the online documentation the calculation is far from converged. With more realistic parameters a larger energy difference of about 0.1 Hartree is obtained.

The spin polarization in the magnetic case is visible if we consider the occupation of the spin-up and spin-down Kohn-Sham orbitals. Especially for the $d$-orbitals these differ rather drastically. For example for the first $k$-point:

iup   = 1
idown = iup + length(scfres.basis.kpoints) ÷ 2
@show scfres.occupation[iup][1:7]
@show scfres.occupation[idown][1:7];
(scfres.occupation[iup])[1:7] = [1.0, 0.9999987822300401, 0.9999987822300392, 0.9999987822300388, 0.958233082883435, 0.95823308286317, 1.1203232925163282e-29]
(scfres.occupation[idown])[1:7] = [1.0, 0.8434849374436983, 0.8434849374209009, 0.8434849373221424, 8.107650853268606e-6, 8.107650851174834e-6, 1.5804169071408764e-32]

Similarly the eigenvalues differ

@show scfres.eigenvalues[iup][1:7]
@show scfres.eigenvalues[idown][1:7];
(scfres.eigenvalues[iup])[1:7] = [-0.06936185012927948, 0.3568823471929968, 0.35688234720052586, 0.35688234720296175, 0.4617373629484124, 0.4617373629534758, 1.1596807317428588]
(scfres.eigenvalues[idown])[1:7] = [-0.031260034752907624, 0.4762233298224342, 0.47622332982416105, 0.47622332983164173, 0.6102941705976779, 0.6102941706002604, 1.225317570734433]
``k``-points in collinear calculations

For collinear calculations the kpoints field of the PlaneWaveBasis object contains each $k$-point coordinate twice, once associated with spin-up and once with down-down. The list first contains all spin-up $k$-points and then all spin-down $k$-points, such that iup and idown index the same $k$-point, but differing spins.

We can observe the spin-polarization by looking at the density of states (DOS) around the Fermi level, where the spin-up and spin-down DOS differ.

using Plots
plot_dos(scfres)

Similarly the band structure shows clear differences between both spin components.

using Unitful
using UnitfulAtomic
plot_bandstructure(scfres; kline_density=6)