Tutorial

This document provides an overview of the structure of the code and how to access basic information about calculations. Basic familiarity with the concepts of plane-wave density functional theory is assumed throughout. Feel free to take a look at the Periodic problems or the Introductory resources chapters for some introductory material on the topic.

For our discussion we will use the classic example of computing the LDA ground state of the silicon crystal. Performing such a calculation roughly proceeds in three steps.

using DFTK
using Plots
using Unitful
using UnitfulAtomic

# 1. Define lattice and atomic positions
a = 5.431u"angstrom"          # Silicon lattice constant
lattice = a / 2 * [[0 1 1.];  # Silicon lattice vectors
                   [1 0 1.];  # specified column by column
                   [1 1 0.]];

By default, all numbers passed as arguments are assumed to be in atomic units. Quantities such as temperature, energy cutoffs, lattice vectors, and the k-point grid spacing can optionally be annotated with Unitful units, which are automatically converted to the atomic units used internally. For more details, see the Unitful package documentation and the UnitfulAtomic.jl package.

# Load HGH pseudopotential for Silicon
Si = ElementPsp(:Si; psp=load_psp("hgh/lda/Si-q4"))

# Specify type and positions of atoms
atoms     = [Si, Si]
positions = [ones(3)/8, -ones(3)/8]

# 2. Select model and basis
model = model_LDA(lattice, atoms, positions)
kgrid = [4, 4, 4]     # k-point grid (Regular Monkhorst-Pack grid)
Ecut = 7              # kinetic energy cutoff
# Ecut = 190.5u"eV"  # Could also use eV or other energy-compatible units
basis = PlaneWaveBasis(model; Ecut, kgrid)
# Note the implicit passing of keyword arguments here:
# this is equivalent to PlaneWaveBasis(model; Ecut=Ecut, kgrid=kgrid)

# 3. Run the SCF procedure to obtain the ground state
scfres = self_consistent_field(basis, tol=1e-5);

n     Energy            log10(ΔE)   log10(Δρ)   Diag   Δtime
---   ---------------   ---------   ---------   ----   ------
  1   -7.900397768214                   -0.70    4.8
  2   -7.904989796798       -2.34       -1.52    1.0   22.3ms
  3   -7.905174425414       -3.73       -2.53    1.1   23.1ms
  4   -7.905210589678       -4.44       -2.83    2.9   32.8ms
  5   -7.905211060153       -6.33       -2.94    1.1   23.3ms
  6   -7.905211519603       -6.34       -4.63    1.0   22.8ms
  7   -7.905211531197       -7.94       -4.66    3.2   36.5ms
  8   -7.905211531388       -9.72       -5.20    1.0   24.4ms

That's it! Now you can get various quantities from the result of the SCF. For instance, the different components of the energy:

scfres.energies

Energy breakdown (in Ha):
    Kinetic             3.1020963 
    AtomicLocal         -2.1987843
    AtomicNonlocal      1.7296093 
    Ewald               -8.3979253
    PspCorrection       -0.2946254
    Hartree             0.5530391 
    Xc                  -2.3986212

    total               -7.905211531388

Eigenvalues:

hcat(scfres.eigenvalues...)

7×8 Matrix{Float64}:
 -0.176942  -0.14744   -0.0911692   …  -0.101219   -0.023977  -0.0184079
  0.261073   0.116915   0.00482509      0.0611643  -0.023977  -0.0184079
  0.261073   0.23299    0.216733        0.121636    0.155532   0.117747
  0.261073   0.23299    0.216733        0.212134    0.155532   0.117747
  0.354532   0.335109   0.317102        0.350436    0.285692   0.417258
  0.354532   0.389829   0.384601    …   0.436925    0.285692   0.417301
  0.354534   0.389829   0.384601        0.449234    0.627541   0.443806

eigenvalues is an array (indexed by k-points) of arrays (indexed by eigenvalue number). The "splatting" operation ... calls hcat with all the inner arrays as arguments, which collects them into a matrix.

The resulting matrix is 7 (number of computed eigenvalues) by 8 (number of irreducible k-points). There are 7 eigenvalues per k-point because there are 4 occupied states in the system (4 valence electrons per silicon atom, two atoms per unit cell, and paired spins), and the eigensolver gives itself some breathing room by computing some extra states (see the bands argument to self_consistent_field as well as the AdaptiveBands documentation). There are only 8 k-points (instead of 4x4x4) because symmetry has been used to reduce the amount of computations to just the irreducible k-points (see Crystal symmetries for details).

We can check the occupations ...

hcat(scfres.occupation...)

7×8 Matrix{Float64}:
 2.0  2.0  2.0  2.0  2.0  2.0  2.0  2.0
 2.0  2.0  2.0  2.0  2.0  2.0  2.0  2.0
 2.0  2.0  2.0  2.0  2.0  2.0  2.0  2.0
 2.0  2.0  2.0  2.0  2.0  2.0  2.0  2.0
 0.0  0.0  0.0  0.0  0.0  0.0  0.0  0.0
 0.0  0.0  0.0  0.0  0.0  0.0  0.0  0.0
 0.0  0.0  0.0  0.0  0.0  0.0  0.0  0.0

... and density, where we use that the density objects in DFTK are indexed as ρ[iσ, ix, iy, iz], i.e. first in the spin component and then in the 3-dimensional real-space grid.

rvecs = collect(r_vectors(basis))[:, 1, 1]  # slice along the x axis
x = [r[1] for r in rvecs]                   # only keep the x coordinate
plot(x, scfres.ρ[1, :, 1, 1], label="", xlabel="x", ylabel="ρ", marker=2)

We can also perform various postprocessing steps: for instance compute a band structure

plot_bandstructure(scfres; kline_density=10)

or get the cartesian forces (in Hartree / Bohr)

compute_forces_cart(scfres)

2-element Vector{StaticArraysCore.SVector{3, Float64}}:
 [-4.50196776755928e-16, -4.279726202084118e-16, -3.442870985032012e-16]
 [-3.446587890985473e-16, -1.6153518535260203e-16, 3.0851814346259097e-16]

As expected, they are numerically zero in this highly symmetric configuration.