Collinear spin and magnetic systems
In this example we consider iron in the BCC phase. To show that this material is ferromagnetic we will model it once allowing collinear spin polarization and once without and compare the resulting SCF energies. In particular the ground state can only be found if collinear spins are allowed.
First we setup BCC iron without spin polarization using a single iron atom inside the unit cell.
using DFTK
a = 5.42352 # Bohr
lattice = a / 2 * [[-1 1 1];
[ 1 -1 1];
[ 1 1 -1]]
Fe = ElementPsp(:Fe, psp=load_psp("hgh/lda/Fe-q8.hgh"))
atoms = [Fe => [zeros(3)]];To get the ground-state energy we use an LDA model and rather moderate discretisation parameters.
kgrid = [3, 3, 3] # k-point grid (Regular Monkhorst-Pack grid)
Ecut = 15 # kinetic energy cutoff in Hartree
model_nospin = model_LDA(lattice, atoms, temperature=0.01)
basis_nospin = PlaneWaveBasis(model_nospin; kgrid, Ecut)
scfres_nospin = self_consistent_field(basis_nospin, tol=1e-6, mixing=KerkerMixing());n Free energy Eₙ-Eₙ₋₁ ρout-ρin α Diag --- --------------- --------- -------- ---- ---- 1 -16.64705838029 NaN 3.28e-01 0.80 5.0 2 -16.64775273766 -6.94e-04 7.78e-02 0.80 1.0 3 -16.64782656818 -7.38e-05 3.18e-03 0.80 2.2 4 -16.64783325784 -6.69e-06 1.61e-03 0.80 3.5 5 -16.64783428438 -1.03e-06 2.24e-04 0.80 2.0 6 -16.64783431088 -2.65e-08 2.36e-05 0.80 2.0
scfres_nospin.energiesEnergy breakdown:
Kinetic 15.9224422
AtomicLocal -5.0701433
AtomicNonlocal -5.2211643
Ewald -21.4723040
PspCorrection 1.8758831
Hartree 0.7795785
Xc -3.4438381
Entropy -0.0182884
total -16.647834310881
Since we did not specify any initial magnetic moment on the iron atom, DFTK will automatically assume that a calculation with only spin-paired electrons should be performed. As a result the obtained ground state features no spin-polarization.
Now we repeat the calculation, but give the iron atom an initial magnetic moment. For specifying the magnetic moment pass the desired excess of spin-up over spin-down electrons at each centre to the Model and the guess density functions. In this case we seek the state with as many spin-parallel $d$-electrons as possible. In our pseudopotential model the 8 valence electrons are 2 pair of $s$-electrons, 1 pair of $d$-electrons and 4 unpaired $d$-electrons giving a desired magnetic moment of 4 at the iron centre. The structure (i.e. pair mapping and order) of the magnetic_moments array needs to agree with the atoms array and 0 magnetic moments need to be specified as well.
magnetic_moments = [Fe => [4, ]];Unlike all other quantities magnetisation and magnetic moments in DFTK are given in units of the Bohr magneton $μ_B$, which in atomic units has the value $\frac{1}{2}$. Since $μ_B$ is (roughly) the magnetic moment of a single electron the advantage is that one can directly think of these quantities as the excess of spin-up electrons or spin-up electron density.
We repeat the calculation using the same model as before. DFTK now detects the non-zero moment and switches to a collinear calculation.
model = model_LDA(lattice, atoms, magnetic_moments=magnetic_moments, temperature=0.01)
basis = PlaneWaveBasis(model; Ecut, kgrid)
ρ0 = guess_density(basis, magnetic_moments)
scfres = self_consistent_field(basis, tol=1e-6; ρ=ρ0, mixing=KerkerMixing());n Free energy Eₙ-Eₙ₋₁ ρout-ρin Magnet α Diag --- --------------- --------- -------- ------ ---- ---- 1 -16.65998301674 NaN 3.11e-01 2.620 0.80 4.5 2 -16.66626408869 -6.28e-03 6.97e-02 2.428 0.80 1.0 3 -16.66694944615 -6.85e-04 9.40e-03 2.349 0.80 2.9 4 -16.66698696712 -3.75e-05 4.32e-03 2.320 0.80 2.9 5 -16.66699447041 -7.50e-06 1.79e-03 2.309 0.80 2.1 6 -16.66699630970 -1.84e-06 5.51e-04 2.301 0.80 1.5 7 -16.66699651905 -2.09e-07 4.50e-05 2.297 0.80 1.5
scfres.energiesEnergy breakdown:
Kinetic 16.3014887
AtomicLocal -5.2260134
AtomicNonlocal -5.4135611
Ewald -21.4723040
PspCorrection 1.8758831
Hartree 0.8201270
Xc -3.5395393
Entropy -0.0130776
total -16.666996519047
DFTK does not store the magnetic_moments inside the Model, but only uses them to determine the lattice symmetries. This step was taken to keep Model (which contains the physical model) independent of the details of the numerical details such as the initial guess for the spin density.
In direct comparison we notice the first, spin-paired calculation to be a little higher in energy
println("No magnetization: ", scfres_nospin.energies.total)
println("Magnetic case: ", scfres.energies.total)
println("Difference: ", scfres.energies.total - scfres_nospin.energies.total);No magnetization: -16.64783431088077 Magnetic case: -16.666996519046652 Difference: -0.019162208165880656
Notice that with the small cutoffs we use to generate the online documentation the calculation is far from converged. With more realistic parameters a larger energy difference of about 0.1 Hartree is obtained.
The spin polarization in the magnetic case is visible if we consider the occupation of the spin-up and spin-down Kohn-Sham orbitals. Especially for the $d$-orbitals these differ rather drastically. For example for the first $k$-point:
iup = 1
idown = iup + length(scfres.basis.kpoints) ÷ 2
@show scfres.occupation[iup][1:7]
@show scfres.occupation[idown][1:7];(scfres.occupation[iup])[1:7] = [1.0, 0.9999988144199191, 0.9999988144132951, 0.9999988144098305, 0.9585784247743196, 0.9585779421648205, 1.1545123998254758e-29] (scfres.occupation[idown])[1:7] = [1.0, 0.8324121391314594, 0.8324101420123445, 0.8324101042355484, 7.827180894065745e-6, 7.827104699891584e-6, 1.5493749078354822e-32]
Similarly the eigenvalues differ
@show scfres.eigenvalues[iup][1:7]
@show scfres.eigenvalues[idown][1:7];(scfres.eigenvalues[iup])[1:7] = [-0.06926999278253584, 0.3568780624140898, 0.3568781182856761, 0.3568781475069792, 0.4619143394553571, 0.4619144610009411, 1.1596437304583371] (scfres.eigenvalues[idown])[1:7] = [-0.03040197811401168, 0.47730263517725646, 0.47730277833700907, 0.477302781044955, 0.6109098376384201, 0.6109099349852714, 1.225779548506774]
For collinear calculations the kpoints field of the PlaneWaveBasis object contains each $k$-point coordinate twice, once associated with spin-up and once with down-down. The list first contains all spin-up $k$-points and then all spin-down $k$-points, such that iup and idown index the same $k$-point, but differing spins.
We can observe the spin-polarization by looking at the density of states (DOS) around the Fermi level, where the spin-up and spin-down DOS differ.
using Plots
plot_dos(scfres)Similarly the band structure shows clear differences between both spin components.
using Unitful
using UnitfulAtomic
plot_bandstructure(scfres, kline_density=3, unit=u"hartree")