Hubbard correction (DFT+U)
In this example, we'll plot the DOS and projected DOS of Nickel Oxide with and without the Hubbard term correction.
using DFTK
using PseudoPotentialData
using Unitful
using UnitfulAtomic
using PlotsDefine the geometry and pseudopotential
a = 7.9 # Nickel Oxide lattice constant in Bohr
lattice = a * [[ 1.0 0.5 0.5];
[ 0.5 1.0 0.5];
[ 0.5 0.5 1.0]]
pseudopotentials = PseudoFamily("dojo.nc.sr.pbe.v0_4_1.standard.upf")
Ni = ElementPsp(:Ni, pseudopotentials)
O = ElementPsp(:O, pseudopotentials)
atoms = [Ni, O, Ni, O]
positions = [zeros(3), ones(3) / 4, ones(3) / 2, ones(3) * 3 / 4]
magnetic_moments = [2, 0, -1, 0]4-element Vector{Int64}:
2
0
-1
0First, we run an SCF and band computation without the Hubbard term
model = model_DFT(lattice, atoms, positions; temperature=5e-3,
functionals=PBE(), magnetic_moments)
basis = PlaneWaveBasis(model; Ecut=20, kgrid=[2, 2, 2])
scfres = self_consistent_field(basis; tol=1e-6, ρ=guess_density(basis, magnetic_moments))
bands = compute_bands(scfres, MonkhorstPack(4, 4, 4))
lowest_unocc_band = findfirst(ε -> ε-bands.εF > 0, bands.eigenvalues[1])
band_gap = bands.eigenvalues[1][lowest_unocc_band] - bands.eigenvalues[1][lowest_unocc_band-1]0.08219293437525416Then we plot the DOS and the PDOS for the relevant 3D (pseudo)atomic projector
εF = bands.εF
width = 5.0u"eV"
εrange = (εF - austrip(width), εF + austrip(width))
p = plot_dos(bands; εrange, colors=[:red, :red])
plot_pdos(bands; p, iatom=1, label="3D", colors=[:yellow, :orange], εrange)
To perform and Hubbard computation, we have to define the Hubbard manifold and associated constant.
In DFTK there are a few ways to construct the OrbitalManifold. Here, we will apply the Hubbard correction on the 3D orbital of all nickel atoms. To select all nickel atoms, we can:
- Pass the
Nielement directly. - Pass the
:Nisymbol. - Pass the list of atom indices, here
[1, 3].
To select the orbitals, it is recommended to use their label, such as "3D" for PseudoDojo pseudopotentials.
Note that "manifold" is the standard term used in the literature for the set of atomic orbitals used to compute the Hubbard correction, but it is not meant in the mathematical sense.
U = 10u"eV"
# Alternative:
# manifold = OrbitalManifold(:Ni, "3D")
# Alternative:
# manifold = OrbitalManifold([1, 3], "3D")
manifold = OrbitalManifold(Ni, "3D")OrbitalManifold(Ni, "3D")Run SCF with a DFT+U setup, notice the extra_terms keyword argument, setting up the Hubbard +U term. It is also possible to set up multiple manifolds with different U values by passing each pair as a separate entry in the Hubbard constructor (i.e. Hubbard(manifold1 => U1, manifold2 => U2, etc.)) or as two vectors (i.e. Hubbard([manifold1, manifold2, etc.], [U1, U2, etc.])).
model = model_DFT(lattice, atoms, positions; extra_terms=[Hubbard(manifold => U)],
functionals=PBE(), temperature=5e-3, magnetic_moments)
basis = PlaneWaveBasis(model; Ecut=20, kgrid=[2, 2, 2])
scfres = self_consistent_field(basis; tol=1e-6, ρ=guess_density(basis, magnetic_moments));┌ Warning: Negative ρcore detected: -0.0006182370306135084
└ @ DFTK ~/work/DFTK.jl/DFTK.jl/src/terms/xc.jl:39
n Energy log10(ΔE) log10(Δρ) Magnet |Magn| Diag Δtime
--- --------------- --------- --------- ------ ------ ---- ------
1 -361.3857461090 0.07 1.335 3.441 6.9 5.46s
2 -363.2374057658 0.27 -0.21 0.014 3.624 3.2 3.68s
3 -363.3511551154 -0.94 -0.58 0.000 3.727 3.2 2.95s
4 -363.3890413532 -1.42 -1.18 0.000 3.717 2.5 2.46s
5 -363.3959775150 -2.16 -1.67 0.000 3.681 2.0 2.27s
6 -363.3973153761 -2.87 -2.04 0.000 3.656 1.5 1.94s
7 -363.3976106158 -3.53 -2.28 0.000 3.647 2.4 2.20s
8 -363.3976904964 -4.10 -2.62 0.000 3.647 1.4 1.96s
9 -363.3977069766 -4.78 -2.99 0.000 3.649 2.0 2.22s
10 -363.3977065623 + -6.38 -2.94 -0.000 3.649 2.0 2.06s
11 -363.3977093289 -5.56 -3.21 0.000 3.648 2.0 2.10s
12 -363.3977093339 -8.30 -3.31 0.000 3.648 1.8 1.98s
13 -363.3977086824 + -6.19 -3.13 -0.000 3.648 2.0 2.09s
14 -363.3977087104 -7.55 -3.10 -0.000 3.648 1.0 1.70s
15 -363.3977078604 + -6.07 -2.77 -0.000 3.648 1.5 1.80s
16 -363.3977097617 -5.72 -3.38 -0.000 3.649 2.2 2.13s
17 -363.3977098377 -7.12 -3.28 -0.000 3.649 1.0 1.69s
18 -363.3977099044 -7.18 -3.29 -0.000 3.649 1.4 1.75s
19 -363.3977098235 + -7.09 -3.29 -0.000 3.649 1.1 1.71s
20 -363.3977095420 + -6.55 -3.28 0.000 3.649 1.6 1.83s
21 -363.3977095452 -8.50 -3.30 0.000 3.648 1.0 1.70s
22 -363.3977095016 + -7.36 -3.28 0.000 3.648 1.0 1.70s
23 -363.3977095634 -7.21 -3.30 0.000 3.648 1.0 1.70s
24 -363.3977097345 -6.77 -3.37 0.000 3.648 1.0 3.10s
25 -363.3977099404 -6.69 -3.52 -0.000 3.648 1.0 1.67s
26 -363.3977099887 -7.32 -3.59 -0.000 3.648 1.0 1.73s
27 -363.3977100135 -7.61 -4.02 -0.000 3.648 1.2 1.73s
28 -363.3977100083 + -8.28 -4.09 -0.000 3.648 2.4 2.13s
29 -363.3977100088 -9.23 -4.14 0.000 3.648 1.0 1.70s
30 -363.3977100154 -8.19 -4.37 0.000 3.648 1.0 1.70s
31 -363.3977100170 -8.78 -4.71 0.000 3.648 1.1 1.72s
32 -363.3977100176 -9.22 -4.99 0.000 3.648 1.9 1.93s
33 -363.3977100177 -9.96 -5.14 0.000 3.648 1.5 1.79s
34 -363.3977100178 -9.97 -5.82 0.000 3.648 2.0 2.04s
35 -363.3977100178 -11.19 -5.84 0.000 3.648 2.8 2.30s
36 -363.3977100178 -11.88 -5.82 0.000 3.648 1.0 1.69s
37 -363.3977100179 -11.46 -6.62 0.000 3.648 1.1 1.74sRun band computation
bands_hub = compute_bands(scfres, MonkhorstPack(4, 4, 4))
lowest_unocc_band = findfirst(ε -> ε-bands_hub.εF > 0, bands_hub.eigenvalues[1])
band_gap = bands_hub.eigenvalues[1][lowest_unocc_band] - bands_hub.eigenvalues[1][lowest_unocc_band-1]0.11667615723951719With the electron localization introduced by the Hubbard term, the band gap has now opened, reflecting the experimental insulating behaviour of Nickel Oxide.
εF = bands_hub.εF
εrange = (εF - austrip(width), εF + austrip(width))
p = plot_dos(bands_hub; p, colors=[:blue, :blue], εrange)
plot_pdos(bands_hub; p, iatom=1, label="3D", colors=[:green, :purple], εrange)