Collinear spin and magnetic systems
In this example we consider iron in the BCC phase. To show that this material is ferromagnetic we will model it once allowing collinear spin polarization and once without and compare the resulting SCF energies. In particular the ground state can only be found if collinear spins are allowed.
First we setup BCC iron without spin polarization using a single iron atom inside the unit cell.
using DFTK
a = 5.42352 # Bohr
lattice = a / 2 * [[-1 1 1];
[ 1 -1 1];
[ 1 1 -1]]
atoms = [ElementPsp(:Fe, load_psp("hgh/lda/Fe-q8.hgh"))]
positions = [zeros(3)];To get the ground-state energy we use an LDA model and rather moderate discretisation parameters.
kgrid = [3, 3, 3] # k-point grid (Regular Monkhorst-Pack grid)
Ecut = 15 # kinetic energy cutoff in Hartree
model_nospin = model_DFT(lattice, atoms, positions; functionals=LDA(), temperature=0.01)
basis_nospin = PlaneWaveBasis(model_nospin; kgrid, Ecut)
scfres_nospin = self_consistent_field(basis_nospin; tol=1e-4, mixing=KerkerDosMixing());n Energy log10(ΔE) log10(Δρ) Diag Δtime
--- --------------- --------- --------- ---- ------
1 -16.65011497268 -0.48 5.5 117ms
2 -16.65072108952 -3.22 -1.01 1.0 188ms
3 -16.65081301293 -4.04 -2.32 1.5 15.3ms
4 -16.65082391005 -4.96 -2.84 2.0 18.2ms
5 -16.65082460594 -6.16 -3.26 1.5 16.1ms
6 -16.65082468075 -7.13 -3.80 1.2 14.7ms
7 -16.65082469714 -7.79 -4.28 2.0 17.8msscfres_nospin.energiesEnergy breakdown (in Ha):
Kinetic 15.9207737
AtomicLocal -5.0692843
AtomicNonlocal -5.2201918
Ewald -21.4723040
PspCorrection 1.8758831
Hartree 0.7793329
Xc -3.4467465
Entropy -0.0182879
total -16.650824697140Since we did not specify any initial magnetic moment on the iron atom, DFTK will automatically assume that a calculation with only spin-paired electrons should be performed. As a result the obtained ground state features no spin-polarization.
Now we repeat the calculation, but give the iron atom an initial magnetic moment. For specifying the magnetic moment pass the desired excess of spin-up over spin-down electrons at each centre to the Model and the guess density functions. In this case we seek the state with as many spin-parallel $d$-electrons as possible. In our pseudopotential model the 8 valence electrons are 1 pair of $s$-electrons, 1 pair of $d$-electrons and 4 unpaired $d$-electrons giving a desired magnetic moment of 4 at the iron centre. The structure (i.e. pair mapping and order) of the magnetic_moments array needs to agree with the atoms array and 0 magnetic moments need to be specified as well.
magnetic_moments = [4];Unlike all other quantities magnetisation and magnetic moments in DFTK are given in units of the Bohr magneton $μ_B$, which in atomic units has the value $\frac{1}{2}$. Since $μ_B$ is (roughly) the magnetic moment of a single electron the advantage is that one can directly think of these quantities as the excess of spin-up electrons or spin-up electron density.
We repeat the calculation using the same model as before. DFTK now detects the non-zero moment and switches to a collinear calculation.
model = model_DFT(lattice, atoms, positions; functionals=LDA(),
magnetic_moments, temperature=0.01)
basis = PlaneWaveBasis(model; Ecut, kgrid)
ρ0 = guess_density(basis, magnetic_moments)
scfres = self_consistent_field(basis, tol=1e-6; ρ=ρ0, mixing=KerkerDosMixing());n Energy log10(ΔE) log10(Δρ) Magnet Diag Δtime
--- --------------- --------- --------- ------ ---- ------
1 -16.66167518393 -0.51 2.618 5.5 54.9ms
2 -16.66826780335 -2.18 -1.09 2.445 1.5 29.0ms
3 -16.66905666186 -3.10 -2.07 2.341 2.0 62.1ms
4 -16.66909805317 -4.38 -2.60 2.305 1.2 27.6ms
5 -16.66910290416 -5.31 -2.99 2.296 1.9 32.7ms
6 -16.66910413353 -5.91 -3.54 2.287 1.6 31.3ms
7 -16.66910417154 -7.42 -3.80 2.286 2.0 33.9ms
8 -16.66910417444 -8.54 -4.25 2.286 1.6 31.8ms
9 -16.66910417498 -9.27 -4.76 2.286 1.8 32.2ms
10 -16.66910417510 -9.93 -5.29 2.286 1.9 50.7ms
11 -16.66910417508 + -10.73 -5.82 2.286 1.9 33.7ms
12 -16.66910417509 -10.96 -6.37 2.286 1.4 29.9msscfres.energiesEnergy breakdown (in Ha):
Kinetic 16.2947200
AtomicLocal -5.2227264
AtomicNonlocal -5.4100284
Ewald -21.4723040
PspCorrection 1.8758831
Hartree 0.8191963
Xc -3.5406836
Entropy -0.0131612
total -16.669104175088DFTK does not store the magnetic_moments inside the Model, but only uses them to determine the lattice symmetries. This step was taken to keep Model (which contains the physical model) independent of the details of the numerical details such as the initial guess for the spin density.
In direct comparison we notice the first, spin-paired calculation to be a little higher in energy
println("No magnetization: ", scfres_nospin.energies.total)
println("Magnetic case: ", scfres.energies.total)
println("Difference: ", scfres.energies.total - scfres_nospin.energies.total);No magnetization: -16.650824697139623
Magnetic case: -16.669104175088105
Difference: -0.01827947794848228Notice that with the small cutoffs we use to generate the online documentation the calculation is far from converged. With more realistic parameters a larger energy difference of about 0.1 Hartree is obtained.
The spin polarization in the magnetic case is visible if we consider the occupation of the spin-up and spin-down Kohn-Sham orbitals. Especially for the $d$-orbitals these differ rather drastically. For example for the first $k$-point:
iup = 1
idown = iup + length(scfres.basis.kpoints) ÷ 2
@show scfres.occupation[iup][1:7]
@show scfres.occupation[idown][1:7];(scfres.occupation[iup])[1:7] = [1.0, 0.9999987814446881, 0.9999987814446881, 0.9999987814446881, 0.9582254460553181, 0.9582254460553185, 1.1267215915115705e-29]
(scfres.occupation[idown])[1:7] = [1.0, 0.8438912636185878, 0.8438912636185221, 0.8438912636184679, 8.140750074653659e-6, 8.140750074652661e-6, 1.6207825448733616e-32]Similarly the eigenvalues differ
@show scfres.eigenvalues[iup][1:7]
@show scfres.eigenvalues[idown][1:7];(scfres.eigenvalues[iup])[1:7] = [-0.06935855716435453, 0.3568855622913749, 0.3568855622913753, 0.35688556229137786, 0.4617360389876608, 0.4617360389876607, 1.1596205510943072]
(scfres.eigenvalues[idown])[1:7] = [-0.031257451484064946, 0.4761892872290764, 0.4761892872290814, 0.4761892872290855, 0.6102501967675283, 0.6102501967675296, 1.2250621347291077]For collinear calculations the kpoints field of the PlaneWaveBasis object contains each $k$-point coordinate twice, once associated with spin-up and once with down-down. The list first contains all spin-up $k$-points and then all spin-down $k$-points, such that iup and idown index the same $k$-point, but differing spins.
We can observe the spin-polarization by looking at the density of states (DOS) around the Fermi level, where the spin-up and spin-down DOS differ.
using Plots
bands_666 = compute_bands(scfres, MonkhorstPack(6, 6, 6)) # Increase kgrid to get nicer DOS.
plot_dos(bands_666)
Note that if same k-grid as SCF should be employed, a simple plot_dos(scfres) is sufficient.
Similarly the band structure shows clear differences between both spin components.
using Unitful
using UnitfulAtomic
bands_kpath = compute_bands(scfres; kline_density=6)
plot_bandstructure(bands_kpath)