Hubbard correction (DFT+U)
In this example, we'll plot the DOS and projected DOS of Nickel Oxide with and without the Hubbard term correction.
using DFTK
using PseudoPotentialData
using Unitful
using UnitfulAtomic
using PlotsDefine the geometry and pseudopotential
a = 7.9 # Nickel Oxide lattice constant in Bohr
lattice = a * [[ 1.0 0.5 0.5];
[ 0.5 1.0 0.5];
[ 0.5 0.5 1.0]]
pseudopotentials = PseudoFamily("dojo.nc.sr.pbe.v0_4_1.standard.upf")
Ni = ElementPsp(:Ni, pseudopotentials)
O = ElementPsp(:O, pseudopotentials)
atoms = [Ni, O, Ni, O]
positions = [zeros(3), ones(3) / 4, ones(3) / 2, ones(3) * 3 / 4]
magnetic_moments = [2, 0, -1, 0]4-element Vector{Int64}:
2
0
-1
0First, we run an SCF and band computation without the Hubbard term
model = model_DFT(lattice, atoms, positions; temperature=5e-3,
functionals=PBE(), magnetic_moments)
basis = PlaneWaveBasis(model; Ecut=20, kgrid=[2, 2, 2])
scfres = self_consistent_field(basis; tol=1e-6, ρ=guess_density(basis, magnetic_moments))
bands = compute_bands(scfres, MonkhorstPack(4, 4, 4))
lowest_unocc_band = findfirst(ε -> ε-bands.εF > 0, bands.eigenvalues[1])
band_gap = bands.eigenvalues[1][lowest_unocc_band] - bands.eigenvalues[1][lowest_unocc_band-1]0.08219295773021484Then we plot the DOS and the PDOS for the relevant 3D (pseudo)atomic projector
εF = bands.εF
width = 5.0u"eV"
εrange = (εF - austrip(width), εF + austrip(width))
p = plot_dos(bands; εrange, colors=[:red, :red])
plot_pdos(bands; p, iatom=1, label="3D", colors=[:yellow, :orange], εrange)
To perform and Hubbard computation, we have to define the Hubbard manifold and associated constant.
In DFTK there are a few ways to construct the OrbitalManifold. Here, we will apply the Hubbard correction on the 3D orbital of all nickel atoms. To select all nickel atoms, we can:
- Pass the
Nielement directly. - Pass the
:Nisymbol. - Pass the list of atom indices, here
[1, 3].
To select the orbitals, it is recommended to use their label, such as "3D" for PseudoDojo pseudopotentials.
Note that "manifold" is the standard term used in the literature for the set of atomic orbitals used to compute the Hubbard correction, but it is not meant in the mathematical sense.
U = 10u"eV"
# Alternative:
# manifold = OrbitalManifold(:Ni, "3D")
# Alternative:
# manifold = OrbitalManifold([1, 3], "3D")
manifold = OrbitalManifold(Ni, "3D")OrbitalManifold(Ni, "3D")Run SCF with a DFT+U setup, notice the extra_terms keyword argument, setting up the Hubbard +U term. It is also possible to set up multiple manifolds with different U values by passing each pair as a separate entry in the Hubbard constructor (i.e. Hubbard(manifold1 => U1, manifold2 => U2, etc.)) or as two vectors (i.e. Hubbard([manifold1, manifold2, etc.], [U1, U2, etc.])).
model = model_DFT(lattice, atoms, positions; extra_terms=[Hubbard(manifold => U)],
functionals=PBE(), temperature=5e-3, magnetic_moments)
basis = PlaneWaveBasis(model; Ecut=20, kgrid=[2, 2, 2])
scfres = self_consistent_field(basis; tol=1e-6, ρ=guess_density(basis, magnetic_moments));┌ Warning: Negative ρcore detected: -0.000618237030613506
└ @ DFTK ~/work/DFTK.jl/DFTK.jl/src/terms/xc.jl:39
n Energy log10(ΔE) log10(Δρ) Magnet |Magn| Diag Δtime
--- --------------- --------- --------- ------ ------ ---- ------
1 -361.3860107060 0.07 1.335 3.441 6.9 4.15s
2 -363.2384021354 0.27 -0.21 0.014 3.623 3.1 8.46s
3 -363.3509144456 -0.95 -0.58 0.000 3.727 3.2 3.43s
4 -363.3890010876 -1.42 -1.18 0.000 3.717 2.6 2.43s
5 -363.3959626723 -2.16 -1.66 0.000 3.681 2.1 2.76s
6 -363.3973183677 -2.87 -2.04 0.000 3.656 1.5 1.88s
7 -363.3976026516 -3.55 -2.27 0.000 3.647 2.1 2.07s
8 -363.3976852925 -4.08 -2.56 0.000 3.647 1.5 2.49s
9 -363.3977062410 -4.68 -2.93 0.000 3.649 2.0 2.17s
10 -363.3977065023 -6.58 -2.91 -0.000 3.649 1.9 1.99s
11 -363.3977087269 -5.65 -3.08 -0.000 3.649 1.0 2.31s
12 -363.3977090750 -6.46 -3.03 -0.000 3.648 1.0 1.77s
13 -363.3977096402 -6.25 -2.96 0.000 3.648 1.0 1.77s
14 -363.3977073925 + -5.65 -2.69 0.000 3.647 2.0 2.67s
15 -363.3977082542 -6.06 -2.70 0.000 3.647 1.0 1.79s
16 -363.3977088350 -6.24 -2.63 -0.000 3.648 1.0 1.77s
17 -363.3977085871 + -6.61 -2.59 -0.000 3.648 1.0 2.31s
18 -363.3977086470 -7.22 -2.59 -0.000 3.648 1.0 1.80s
19 -363.3977083602 + -6.54 -2.54 -0.000 3.647 1.0 1.77s
20 -363.3977091734 -6.09 -2.65 -0.000 3.648 1.0 2.37s
21 -363.3977097309 -6.25 -2.84 -0.000 3.648 1.0 1.82s
22 -363.3977098377 -6.97 -2.91 -0.000 3.648 1.0 1.77s
23 -363.3977099134 -7.12 -3.28 -0.000 3.649 1.0 1.77s
24 -363.3977098893 + -7.62 -3.27 -0.000 3.649 1.0 2.24s
25 -363.3977099338 -7.35 -3.29 -0.000 3.649 1.0 1.69s
26 -363.3977099572 -7.63 -3.36 -0.000 3.649 1.0 1.65s
27 -363.3977099620 -8.32 -3.57 -0.000 3.649 1.0 1.73s
28 -363.3977099617 + -9.56 -3.62 -0.000 3.649 1.0 2.18s
29 -363.3977099700 -8.08 -3.84 -0.000 3.649 1.0 1.66s
30 -363.3977099851 -7.82 -3.91 -0.000 3.649 1.0 1.66s
31 -363.3977099948 -8.01 -3.99 -0.000 3.649 1.0 2.23s
32 -363.3977100067 -7.92 -4.15 -0.000 3.648 1.0 1.66s
33 -363.3977100153 -8.07 -4.35 -0.000 3.648 1.9 1.85s
34 -363.3977100147 + -9.23 -4.28 -0.000 3.648 1.4 1.73s
35 -363.3977100171 -8.63 -4.65 -0.000 3.648 1.0 2.24s
36 -363.3977100177 -9.17 -5.07 0.000 3.648 2.0 1.96s
37 -363.3977100177 + -10.96 -5.07 0.000 3.648 1.1 1.69s
38 -363.3977100178 -10.27 -5.27 0.000 3.648 1.0 2.24s
39 -363.3977100178 -10.28 -5.92 0.000 3.648 1.6 1.78s
40 -363.3977100178 -11.45 -5.90 0.000 3.648 2.5 2.02s
41 -363.3977100178 -11.51 -5.90 0.000 3.648 1.0 1.67s
42 -363.3977100179 -11.73 -6.05 0.000 3.648 1.0 2.23s
Run band computation
bands_hub = compute_bands(scfres, MonkhorstPack(4, 4, 4))
lowest_unocc_band = findfirst(ε -> ε-bands_hub.εF > 0, bands_hub.eigenvalues[1])
band_gap = bands_hub.eigenvalues[1][lowest_unocc_band] - bands_hub.eigenvalues[1][lowest_unocc_band-1]0.11667620379278865With the electron localization introduced by the Hubbard term, the band gap has now opened, reflecting the experimental insulating behaviour of Nickel Oxide.
εF = bands_hub.εF
εrange = (εF - austrip(width), εF + austrip(width))
p = plot_dos(bands_hub; p, colors=[:blue, :blue], εrange)
plot_pdos(bands_hub; p, iatom=1, label="3D", colors=[:green, :purple], εrange)