Polarizability using automatic differentiation

Simple example for computing properties using (forward-mode) automatic differentiation. For a more classical approach and more details about computing polarizabilities, see Polarizability by linear response.

using DFTK
using LinearAlgebra
using ForwardDiff
using PseudoPotentialData

# Construct PlaneWaveBasis given a particular electric field strength
# Again we take the example of a Helium atom.
function make_basis(ε::T; a=10., Ecut=30) where {T}
    lattice = T(a) * I(3)  # lattice is a cube of ``a`` Bohrs
    # Helium at the center of the box
    pseudopotentials = PseudoFamily("cp2k.nc.sr.lda.v0_1.semicore.gth")
    atoms     = [ElementPsp(:He, pseudopotentials)]
    positions = [[1/2, 1/2, 1/2]]

    model = model_DFT(lattice, atoms, positions;
                      functionals=[:lda_x, :lda_c_vwn],
                      extra_terms=[ExternalFromReal(r -> -ε * (r[1] - a/2))],
                      symmetries=false)
    PlaneWaveBasis(model; Ecut, kgrid=[1, 1, 1])  # No k-point sampling on isolated system
end

# dipole moment of a given density (assuming the current geometry)
function dipole(basis, ρ)
    @assert isdiag(basis.model.lattice)
    a  = basis.model.lattice[1, 1]
    rr = [a * (r[1] - 1/2) for r in r_vectors(basis)]
    sum(rr .* ρ) * basis.dvol
end

# Function to compute the dipole for a given field strength
function compute_dipole(ε; tol=1e-8, kwargs...)
    scfres = self_consistent_field(make_basis(ε; kwargs...); tol)
    dipole(scfres.basis, scfres.ρ)
end;

With this in place we can compute the polarizability from finite differences (just like in the previous example):

polarizability_fd = let
    ε = 0.01
    (compute_dipole(ε) - compute_dipole(0.0)) / ε
end

1.7735579711197438

We do the same thing using automatic differentiation. Under the hood this uses custom rules to implicitly differentiate through the self-consistent field fixed-point problem. This leads to a density-functional perturbation theory problem, which is automatically set up and solved in the background.

polarizability = ForwardDiff.derivative(compute_dipole, 0.0)
println()
println("Polarizability via ForwardDiff:       $polarizability")
println("Polarizability via finite difference: $polarizability_fd")

n     Energy            log10(ΔE)   log10(Δρ)   Diag   Δtime
---   ---------------   ---------   ---------   ----   ------
  1   -2.770882980773                   -0.53    9.0    232ms
  2   -2.772058184830       -2.93       -1.31    1.0    134ms
  3   -2.772083178094       -4.60       -2.56    1.0    114ms
  4   -2.772083395287       -6.66       -3.56    1.0    116ms
  5   -2.772083416306       -7.68       -3.96    2.0    138ms
  6   -2.772083417774       -8.83       -5.33    1.0    135ms
  7   -2.772083417810      -10.44       -5.60    2.0    140ms
  8   -2.772083417811      -12.33       -6.31    1.0    121ms
  9   -2.772083417811      -13.64       -6.39    2.0    143ms
 10   -2.772083417811      -13.45       -7.50    1.0    123ms
 11   -2.772083417811   +  -13.68       -8.21    2.0    143ms
Solving response problem
[ Info: GMRES linsolve starts with norm of residual = 4.19e+00
[ Info: GMRES linsolve in iteration 1; step 1: normres = 2.49e-01
[ Info: GMRES linsolve in iteration 1; step 2: normres = 3.76e-03
[ Info: GMRES linsolve in iteration 1; step 3: normres = 2.84e-04
[ Info: GMRES linsolve in iteration 1; step 4: normres = 4.67e-06
[ Info: GMRES linsolve in iteration 1; step 5: normres = 1.08e-08
┌ Info: GMRES linsolve converged at iteration 1, step 6:
│ * norm of residual = 1.13e-09
└ * number of operations = 8

Polarizability via ForwardDiff:       1.7725349880726555
Polarizability via finite difference: 1.7735579711197438