Collinear spin and magnetic systems
In this example we consider iron in the BCC phase. To show that this material is ferromagnetic we will model it once allowing collinear spin polarization and once without and compare the resulting SCF energies. In particular the ground state can only be found if collinear spins are allowed.
The bulk(:Fe) function from AtomsBuilder returns a BCC iron setup with a single iron atom inside the unit cell.
using AtomsBuilder
using PseudoPotentialData
using DFTK
bulk(:Fe)FlexibleSystem(Fe, periodicity = TTT):
cell_vectors : [ -1.435 1.435 1.435;
1.435 -1.435 1.435;
1.435 1.435 -1.435]u"Å"
Atom(Fe, [ 0, 0, 0]u"Å")
First we consider a setup without spin polarization. To get the ground-state energy of this system we use an LDA model and rather moderate discretisation parameters.
Ecut = 15 # kinetic energy cutoff in Hartree
kgrid = [3, 3, 3] # k-point grid (Regular Monkhorst-Pack grid)
pseudopotentials = PseudoFamily("cp2k.nc.sr.lda.v0_1.largecore.gth")
model_nospin = model_DFT(bulk(:Fe); pseudopotentials, functionals=LDA(), temperature=0.01)
basis_nospin = PlaneWaveBasis(model_nospin; kgrid, Ecut)
scfres_nospin = self_consistent_field(basis_nospin; tol=1e-4, mixing=KerkerDosMixing());n Energy log10(ΔE) log10(Δρ) Diag Δtime
--- --------------- --------- --------- ---- ------
1 -16.65014788283 -0.48 5.8 108ms
2 -16.65071428221 -3.25 -1.02 1.0 194ms
3 -16.65082474582 -3.96 -2.31 1.5 16.1ms
4 -16.65083412010 -5.03 -2.85 2.2 18.5ms
5 -16.65083459010 -6.33 -3.42 1.5 15.8ms
6 -16.65083463368 -7.36 -4.02 1.8 17.0msscfres_nospin.energiesEnergy breakdown (in Ha):
Kinetic 15.9207461
AtomicLocal -5.0692491
AtomicNonlocal -5.2201826
Ewald -21.4723279
PspCorrection 1.8758893
Hartree 0.7793232
Xc -3.4467459
Entropy -0.0182879
total -16.650834633684Since we did not specify any initial magnetic moment on the iron atom, DFTK will automatically assume that a calculation with only spin-paired electrons should be performed. As a result the obtained ground state features no spin-polarization.
Now we repeat the calculation, but give the iron atom an initial magnetic moment. For specifying the magnetic moment pass the desired excess of spin-up over spin-down electrons at each centre to the Model and the guess density functions. In this case we seek the state with as many spin-parallel $d$-electrons as possible. In our pseudopotential model the 8 valence electrons are 1 pair of $s$-electrons, 1 pair of $d$-electrons and 4 unpaired $d$-electrons giving a desired magnetic moment of 4 at the iron centre. The structure (i.e. pair mapping and order) of the magnetic_moments array needs to agree with the atoms array and 0 magnetic moments need to be specified as well.
magnetic_moments = [4];Unlike all other quantities magnetisation and magnetic moments in DFTK are given in units of the Bohr magneton $μ_B$, which in atomic units has the value $\frac{1}{2}$. Since $μ_B$ is (roughly) the magnetic moment of a single electron the advantage is that one can directly think of these quantities as the excess of spin-up electrons or spin-up electron density.
We repeat the calculation using the same model as before. DFTK now detects the non-zero moment and switches to a collinear calculation.
model = model_DFT(bulk(:Fe); pseudopotentials, functionals=LDA(),
temperature=0.01, magnetic_moments)
basis = PlaneWaveBasis(model; Ecut, kgrid)
ρ0 = guess_density(basis, magnetic_moments)
scfres = self_consistent_field(basis, tol=1e-6; ρ=ρ0, mixing=KerkerDosMixing());n Energy log10(ΔE) log10(Δρ) Magnet Diag Δtime
--- --------------- --------- --------- ------ ---- ------
1 -16.66148705697 -0.51 2.618 5.6 93.7ms
2 -16.66821898096 -2.17 -1.10 2.443 1.5 30.8ms
3 -16.66906393770 -3.07 -2.08 2.340 2.1 45.1ms
4 -16.66910878800 -4.35 -2.59 2.305 1.4 37.9ms
5 -16.66911253001 -5.43 -2.89 2.297 1.5 30.0ms
6 -16.66911413617 -5.79 -3.50 2.287 1.5 30.8ms
7 -16.66911419886 -7.20 -3.89 2.285 2.1 35.8ms
8 -16.66911420278 -8.41 -4.34 2.286 1.4 29.6ms
9 -16.66911420360 -9.08 -4.91 2.286 1.6 53.2ms
10 -16.66911420357 + -10.55 -5.36 2.286 1.9 34.4ms
11 -16.66911420359 -10.87 -5.72 2.286 1.4 29.9ms
12 -16.66911420358 + -11.02 -6.16 2.286 1.1 28.4msscfres.energiesEnergy breakdown (in Ha):
Kinetic 16.2947698
AtomicLocal -5.2227289
AtomicNonlocal -5.4100655
Ewald -21.4723279
PspCorrection 1.8758893
Hartree 0.8191977
Xc -3.5406876
Entropy -0.0131612
total -16.669114203576DFTK does not store the magnetic_moments inside the Model, but only uses them to determine the lattice symmetries. This step was taken to keep Model (which contains the physical model) independent of the details of the numerical details such as the initial guess for the spin density.
In direct comparison we notice the first, spin-paired calculation to be a little higher in energy
println("No magnetization: ", scfres_nospin.energies.total)
println("Magnetic case: ", scfres.energies.total)
println("Difference: ", scfres.energies.total - scfres_nospin.energies.total);No magnetization: -16.650834633683765
Magnetic case: -16.66911420357625
Difference: -0.018279569892484915Notice that with the small cutoffs we use to generate the online documentation the calculation is far from converged. With more realistic parameters a larger energy difference of about 0.1 Hartree is obtained.
The spin polarization in the magnetic case is visible if we consider the occupation of the spin-up and spin-down Kohn-Sham orbitals. Especially for the $d$-orbitals these differ rather drastically. For example for the first $k$-point:
iup = 1
idown = iup + length(scfres.basis.kpoints) ÷ 2
@show scfres.occupation[iup][1:7]
@show scfres.occupation[idown][1:7];(scfres.occupation[iup])[1:7] = [1.0, 0.9999987814907916, 0.9999987814907916, 0.9999987814907916, 0.9582259917272608, 0.9582259917272415, 1.1263321214154563e-29]
(scfres.occupation[idown])[1:7] = [1.0, 0.8438940477906304, 0.8438940477906304, 0.8438940477906259, 8.140691633112083e-6, 8.1406916331289e-6, 1.5995276269653728e-32]Similarly the eigenvalues differ
@show scfres.eigenvalues[iup][1:7]
@show scfres.eigenvalues[idown][1:7];(scfres.eigenvalues[iup])[1:7] = [-0.0693578310291067, 0.3568863372416748, 0.35688633724167906, 0.35688633724168806, 0.46173705597171166, 0.46173705597171644, 1.1596251616610889]
(scfres.eigenvalues[idown])[1:7] = [-0.031256727796831654, 0.4761902291897726, 0.4761902291897726, 0.47619022918977294, 0.6102514218598172, 0.6102514218597965, 1.2251952953566019]For collinear calculations the kpoints field of the PlaneWaveBasis object contains each $k$-point coordinate twice, once associated with spin-up and once with down-down. The list first contains all spin-up $k$-points and then all spin-down $k$-points, such that iup and idown index the same $k$-point, but differing spins.
We can observe the spin-polarization by looking at the density of states (DOS) around the Fermi level, where the spin-up and spin-down DOS differ.
using Plots
bands_666 = compute_bands(scfres, MonkhorstPack(6, 6, 6)) # Increase kgrid to get nicer DOS.
plot_dos(bands_666)
Note that if same k-grid as SCF should be employed, a simple plot_dos(scfres) is sufficient.
Similarly the band structure shows clear differences between both spin components.
using Unitful
using UnitfulAtomic
bands_kpath = compute_bands(scfres; kline_density=6)
plot_bandstructure(bands_kpath)